[ create a new paste ] login | about

Link: http://codepad.org/1vSQPHC7    [ raw code | fork ]

Plain Text, pasted on Apr 7:
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Scytrin dai Kinthra <scytrin@gmail.com>
_pkgname=st
pkgname=$_pkgname-git
pkgver=0.506.b1813b1
pkgrel=1
pkgdesc="Simple virtual terminal emulator for X"
arch=('i686' 'x86_64' 'armv7h')
url="http://git.suckless.org/st/"
license=('MIT')
depends=('libxft')
makedepends=('git' 'ncurses')
provides=("$_pkgname" "$_pkgname-hg")
conflicts=("$_pkgname" "$_pkgname-hg")
source=("$_pkgname::git+http://git.suckless.org/st")
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  echo "0.$(git rev-list --count HEAD).$(git describe --always)"
}

prepare() {
  cd "$srcdir/$_pkgname"

  # applying patches
  if ls $SRCDEST/*\.diff 2> /dev/null;then for i in $SRCDEST/*\.diff;do msg "applying $i"; git apply $i;done;fi

  # custom config
  if [ -e $SRCDEST/config.h ];then msg "using custom config.h";cp $SRCDEST/config.h .;fi
}

build() {
  cd "$srcdir/$_pkgname"
  make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
}

package() {
  cd "$srcdir/$_pkgname"
  make PREFIX="/usr" DESTDIR="$pkgdir" TERMINFO="$pkgdir/usr/share/terminfo" install
  install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 "README" "$pkgdir/usr/share/doc/$pkgname/README"
}

# vim:set ts=2 sw=2 et:



Create a new paste based on this one


Comments: