# Contributor: danilo <gezuru at gmail dot com>
# Contributor: Jason Begley <jayray at digitalgoat dot com>
# Contributor: Ray Kohler <ataraxia937 at gmail dot com>
# Maintainer: Daniel Riedemann <daniel.riedemann [at] googlemail [dot] com>
# Maintainer: 458italia <svenskaparadox [at] gmail dot com>

pkgname=strongswan
pkgver=4.6.4
pkgrel=1
pkgdesc="open source IPsec implementation"
url='http://www.strongswan.org'
license=("GPL")
arch=('i686' 'x86_64')
depends=('curl' 'gmp' 'iproute2' 'openssl' 'sqlite3')
conflicts=('openswan')
backup=(etc/ipsec.conf etc/strongswan.conf)
source=(http://download.strongswan.org/${pkgname}-${pkgver}.tar.bz2 strongswan.rc::http://pastebin.com/raw.php?i=Qt4aRVEs)
md5sums=('4c0999c42faa0860ae0afc4f8efd9d04'
         '8eeae90374673d10c373a88203d36f8a')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}

  ./configure   --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib --with-ipsecdir=/usr/lib/strongswan \
        --enable-sqlite --enable-cisco-quirks \
        --enable-openssl --enable-curl \
        --enable-sql --enable-attr-sql \
        --enable-farp --enable-dhcp \
        --enable-eap-sim --enable-eap-sim-file --enable-eap-simaka-pseudonym \
        --enable-eap-simaka-reauth --enable-eap-identity --enable-eap-md5 \
        --enable-eap-gtc --enable-eap-aka --enable-eap-aka-3gpp2 \
        --enable-eap-mschapv2 --enable-eap-radius \
        --enable-ha \
        --disable-mysql --disable-ldap \
        --disable-static --enable-shared

  make || return 1
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}

  make DESTDIR=${pkgdir} install

  install -Dm755 ${srcdir}/strongswan.rc ${pkgdir}/etc/rc.d/strongswan
}