[ create a new paste ] login | about

Link: http://codepad.org/ZYKHKHuT    [ raw code | fork ]

Plain Text, pasted on Apr 11:
# Maintainer: Daniel Micay <danielmicay@gmail.com>
# Contributor: Christian Hesse <mail@eworm.de>
# Contributor: Dave Reisner <dreisner@archlinux.org>
# Contributor: Hervé Cauwelier <herve ¤ oursours.net>

_gitname=libgit2
pkgname=libgit2-git
pkgver=0.16.0.2537.gacd4077
pkgrel=1
pkgdesc='a linkable library for git'
arch=('i686' 'x86_64')
url="https://github.com/libgit2/libgit2"
license=('GPL2')
depends=('openssl' 'zlib')
makedepends=('git' 'cmake')
provides=('libgit2')
conflicts=('libgit2')
source=(git://github.com/libgit2/libgit2.git)
md5sums=(SKIP)

pkgver() {
	cd libgit2/
	git describe --tags --long | sed 's|^[^0-9]*||;s|-|.|g'
}

build() {
	cd libgit2/
	cmake . -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr -DBUILD_CLAR=OFF -DTHREADSAFE=ON
	make
}

package() {
	cd libgit2/
	make DESTDIR="${pkgdir}" install
}



Create a new paste based on this one


Comments: