[ create a new paste ] login | about

Link: http://codepad.org/qEpegqCq    [ raw code | output | fork ]

programmingpraxis - Scheme, pasted on Oct 21:
; david gries' coffee can problem

(define rand #f)
(define randint #f)
(let ((two31 #x80000000) (a (make-vector 56 -1)) (fptr #f))
  (define (mod-diff x y) (modulo (- x y) two31)) ; generic version
  ; (define (mod-diff x y) (logand (- x y) #x7FFFFFFF)) ; fast version
  (define (flip-cycle)
    (do ((ii 1 (+ ii 1)) (jj 32 (+ jj 1))) ((< 55 jj))
      (vector-set! a ii (mod-diff (vector-ref a ii) (vector-ref a jj))))
    (do ((ii 25 (+ ii 1)) (jj 1 (+ jj 1))) ((< 55 ii))
      (vector-set! a ii (mod-diff (vector-ref a ii) (vector-ref a jj))))
    (set! fptr 54) (vector-ref a 55))
  (define (init-rand seed)
    (let* ((seed (mod-diff seed 0)) (prev seed) (next 1))
      (vector-set! a 55 prev)
      (do ((i 21 (modulo (+ i 21) 55))) ((zero? i))
        (vector-set! a i next) (set! next (mod-diff prev next))
        (set! seed (+ (quotient seed 2) (if (odd? seed) #x40000000 0)))
        (set! next (mod-diff next seed)) (set! prev (vector-ref a i)))
      (flip-cycle) (flip-cycle) (flip-cycle) (flip-cycle) (flip-cycle)))
  (define (next-rand)
    (if (negative? (vector-ref a fptr)) (flip-cycle)
      (let ((next (vector-ref a fptr))) (set! fptr (- fptr 1)) next)))
  (define (unif-rand m)
    (let ((t (- two31 (modulo two31 m))))
      (let loop ((r (next-rand)))
        (if (<= t r) (loop (next-rand)) (modulo r m)))))
  (init-rand 19380110) ; happy birthday donald e knuth
  (set! rand (lambda seed
    (cond ((null? seed) (/ (next-rand) two31))
          ((eq? (car seed) 'get) (cons fptr (vector->list a)))
          ((eq? (car seed) 'set) (set! fptr (caadr seed))
                                 (set! a (list->vector (cdadr seed))))
          (else (/ (init-rand (modulo (numerator
                  (inexact->exact (car seed))) two31)) two31)))))
  (set! randint (lambda args
    (cond ((null? (cdr args))
            (if (< (car args) two31) (unif-rand (car args))
              (floor (* (next-rand) (car args)))))
          ((< (car args) (cadr args))
            (let ((span (- (cadr args) (car args))))
              (+ (car args)
                 (if (< span two31) (unif-rand span)
                   (floor (* (next-rand) span))))))
          (else (let ((span (- (car args) (cadr args))))
                  (- (car args)
                     (if (< span two31) (unif-rand span)
                       (floor (* (next-rand) span))))))))))

(define-syntax assert
  (syntax-rules ()
    ((assert expr result)
      (if (not (equal? expr result))
          (for-each display `(
            #\newline "failed assertion:" #\newline
            expr #\newline "expected: " ,result
            #\newline "returned: " ,expr #\newline))))))

(define (coffee b w)
  (if (and (zero? b) (= w 1)) 'w
  (if (and (zero? w) (= b 1)) 'b
  (if (and (zero? b) (= w 2)) 'b
  (if (and (zero? w) (= b 2)) 'b
  (if (and (= b 1) (= w 1)) 'w
  (let* ((one (if (< (randint (+ b w)) b) 'b 'w))
         (b (if (eq? one 'b) (- b 1) b))
         (w (if (eq? one 'w) (- w 1) w))
         (two (if (< (randint (+ b w)) b) 'b 'w))
         (b (if (eq? two 'b) (- b 1) b))
         (w (if (eq? two 'w) (- w 1) w)))
    (if (eq? one two)
        (coffee (+ b 1) w)
        (coffee b (+ w 1))))))))))

(display (coffee 5 8)) (newline)
(display (coffee 5 7)) (newline)

(do ((b 1 (+ b 1))) ((= b 50))
  (do ((w 1 (+ w 1))) ((= w 50))
    (if (even? w)
        (assert (coffee b w) 'b)
        (assert (coffee b w) 'w))))


Output:
1
2
b
w


Create a new paste based on this one


Comments: