# Maintainer: Frikilinux <frikilinux at frikilinux.com.ar>

pkgname=faenza-icon-theme
pkgver=1.0
pkgrel=2
pkgdesc="Icon theme designed for Equinox GTK theme"
url="http://gnome-look.org/content/show.php/Faenza?content=128143"
license=('GPL3')
arch=('any')
makedepends=()
options=(!strip)
source=("http://${pkgname}.googlecode.com/files/${pkgname}_${pkgver}.tar.gz")
sha256sums=('43284a172c9370810795163e366315b7d6b8bca85e7bcf0796b5ceb790a3dee4')

package() {
  cd "${srcdir}"
  mkdir -p "${pkgdir}"/usr/share/icons
  cp -Rf Faenza{,-Dark,-Darkest,-Darker} "${pkgdir}"/usr/share/icons/

  # set the Arch Linux Dristributor and start menu logo
  for theme in Faenza{,-Dark}; do
    for size in 22 24 32 48; do
      cd "${pkgdir}"/usr/share/icons/$theme/places/$size
      ln -sf distributor-logo-archlinux.png distributor-logo.png
      ln -sf start-here-archlinux.png start-here.png
    done;
    cd "${pkgdir}"/usr/share/icons/$theme/apps/scalable
    ln -sf distributor-logo-archlinux.svg distributor-logo.svg
    ln -sf start-here-archlinux.svg start-here.svg
  done;

  # set gvim's icon
  for size in 22 24 32 48; do
    cd "${pkgdir}"/usr/share/icons/Faenza/apps/$size
    ln -sf vim.png gvim.png
  done;
  cd "${pkgdir}"/usr/share/icons/Faenza/apps/scalable
  ln -sf vim.svg gvim.svg
}