project(DungeonHack)

cmake_minimum_required(VERSION 2.4)
# For cmake 2.4 backwards compatibility
cmake_policy(SET CMP0003 NEW)
cmake_policy(SET CMP0005 NEW) # Automatically escape preprocessor definitions like 2.6

set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/)

find_package(OGRE REQUIRED)

set(OGRE_PATH $ENV{OGRE_HOME})

# set the OGRE plugins directory
if (WIN32)
    if (OGRE_PATH)
        set(OGRE_PLUGIN_DIR $ENV{OGRE_HOME}/bin/release)
    else (OGRE_PATH)
        set(OGRE_PLUGIN_DIR $ENV{OGRE_SRC}/lib)
    endif (OGRE_PATH)
else (WIN32)
    set(OGRE_PLUGIN_DIR ${OGRE_LIB_DIR}/OGRE)
endif (WIN32)

# list of our required plugins; on win32, put D3D plugin first
set(OGRE_PLUGINS RenderSystem_GL
                 Plugin_ParticleFX
                 Plugin_OctreeSceneManager
                 Plugin_CgProgramManager)
if (WIN32)
    list(INSERT OGRE_PLUGINS 0 RenderSystem_Direct3D9)
endif (WIN32)

# write plugins.cfg
file(WRITE bin/plugins.cfg "PluginFolder=${OGRE_PLUGIN_DIR}\n\n")
foreach (plugin ${OGRE_PLUGINS})
    file(APPEND bin/plugins.cfg "Plugin=${plugin}\n")
endforeach (plugin ${OGRE_PLUGINS})

find_package(OGREPG REQUIRED)
find_package(OIS REQUIRED)
find_package(MYGUI REQUIRED)
find_package(OpenAL REQUIRED)
find_package(ALURE REQUIRED)
find_package(Bullet REQUIRED)
find_package(PythonLibs REQUIRED)
find_package(YamlCpp REQUIRED)
find_package(SWIG REQUIRED)

set(CMAKE_INCLUDE_PATH ${CMAKE_SOURCE_DIR}/cmake/)
include(ConfigPlatform)
include(ConfigDebug)
include(ConfigPackages)

# Set options
option(DH_THREAD_SCRIPTS "Enable possibly unstable script threading" false)
option(DH_EXTRA_OUTPUT "Log lots of extra output. Only needed for debugging situations." false)

if(DH_THREAD_SCRIPTS)
    add_definitions(-DDH_THREAD_SCRIPTS)
endif(DH_THREAD_SCRIPTS)

if(DH_EXTRA_OUTPUT)
    add_definitions(-DDH_EXTRA_OUTPUT)
endif(DH_EXTRA_OUTPUT)

add_subdirectory(src/scripting)
add_subdirectory(src)